[求助]请老师帮忙转换为WH9的模型。 (文华财经wh9)

投资者咨询：[求助]请老师帮忙转换为WH9的模型。 (文华财经wh9)

来源:文华财经日期:2019-11-2 16:15

昨日到现在，一直试着改，但是都不成功，请老师帮忙改为WH9的模型，谢谢！

双划线//的标注请老师帮忙加上，这样才看得懂每一步是如何，便于自学上手

M=23

K=37

RMB=100000

FXL=13

DUN=10

W=47

//日线模型

TR := MAX(MAX((HIGH-LOW),ABS(REF(CLOSE,1)-HIGH)),ABS(REF(CLOSE,1)-LOW));
NN:=IF(BARPOS>14,14,BARPOS);//避免ATR不足14时为空值
ATR :=MA(TR,NN);
RAVI:=ABS(100*(EMA(C,5)-EMA(C,20))/EMA(C,20));
MA50:EMA(C,M);
X:=CEILING((RMB*FXL/100)/(ATR*(K/10)*DUN),1);
BK1:=C>MA50 AND REF(C,1)>REF(MA50,2) AND REF(C,2)>REF(MA50,3) AND C>REF(MA50,1);
BK2:=BK1=1 AND RAVI>=1 AND RAVI>REF(RAVI,1) AND REF(RAVI,1)>REF(RAVI,2) AND BKVOL=0;
BK2=1,BK(X);
SK1:=C<MA50 AND REF(C,1)<REF(MA50,2) AND REF(C,2)<REF(MA50,3) AND C<REF(MA50,1);
SK2:=SK1=1 AND RAVI>=1 AND RAVI>REF(RAVI,1) AND REF(RAVI,1)>REF(RAVI,2) AND SKVOL=0;
SK2=1,SK(X);
//以下为止盈
MONEY1:H-VALUEWHEN(BK2=1,C);
MONEY2:=VALUEWHEN(SK2=1,C)-L;
MONEYB:C-VALUEWHEN(BK2=1,C);
MONEYS:=VALUEWHEN(SK2=1,C)-C;
ATRB:VALUEWHEN(BK2=1,ATR);
ATRS:=VALUEWHEN(SK2=1,ATR);
HVVB:HHV(MONEY1,BARSBK);
HVVS:HHV(MONEY2,BARSSK);
HVVB>=(W/10)*ATRB AND MONEYB<=HVVB/2 AND BKVOL>0,SP(BKVOL);//止盈平仓，卖平
HVVS>=(W/10)*ATRS AND MONEYS<=HVVS/2 AND SKVOL>0,BP(SKVOL);//止盈平仓，买平
//以下为止损
ZSBM:=VALUEWHEN(BK2=1,C)-ATRB*K/10;
ZSSM:=VALUEWHEN(SK2=1,C)+ATRS*K/10;
ZSB:=L<ZSBM AND BKVOL>0;//止损
ZSS:=H>ZSSM AND SKVOL>0;//止损
ZSB=1,SP(BKVOL);
ZSS=1,BP(SKVOL);
C<MA50 AND BKVOL>0,SP(BKVOL);
C>MA50 AND SKVOL>0,BP(SKVOL);

//用指数测试，交易主连合约，模型信号为次日的K线开盘价
TRADE_OTHER('AUTO');//用这个，可以用指数测试，交易主连合约
SETSIGPRICETYPE(SK,NEW_ORDER);//用这个代码，BKPRICE和SKPRICE等都变为次日开盘的价格
SETSIGPRICETYPE(BK,NEW_ORDER);
SETSIGPRICETYPE(SP,NEW_ORDER);
SETSIGPRICETYPE(BP,NEW_ORDER);

投资者咨询：[求助]请老师帮忙转换为WH9的模型。 (文华财经wh9)

来源:文华财经日期:2019-11-2 16:15

顶起，让老师看到~

技术人员回复

日期:2019-11-2 18:13

参考

Setting

Trade_Other:Auto;

Params

Numeric M(23);

Numeric K(37);

Numeric RMB(100000);

Numeric FXL(13);

Numeric DUN(10);

Numeric W(47);

Vars

Numeric TR;

Numeric NN;

Numeric ATR;

Numeric RAVI;

Numeric MA50;

Numeric X;

Numeric BK1;

Numeric BK2;

Numeric SK1;

Numeric SK2;

Numeric MONEY1;

Numeric MONEY2;

Numeric MONEYB;

Numeric MONEYS;

Numeric ATRB;

Numeric ATRS;

Numeric HVVB;

Numeric HVVS;

Numeric ZSBM;

Numeric ZSSM;

Numeric ZSB;

Numeric ZSS;

Begin

//日线模型

TR = MAX(MAX((HIGH-LOW),ABS(REF(CLOSE,1)-HIGH)),ABS(REF(CLOSE,1)-LOW));

NN=IIF(BARPOS>14,14,BARPOS);//避免ATR不足14时为空值

ATR =MA(TR,NN);

RAVI=ABS(100*(EMA(Close,5)-EMA(Close,20))/EMA(Close,20));

MA50=EMA(Close,M);

PlotLine("ma50",MA50,Yellow,Linethick2,2,0);

X=CEILING((RMB*FXL/100)/(ATR*(K/10)*DUN),1);

BK1=Close>MA50 AND REF(Close,1)>REF(MA50,2) AND REF(Close,2)>REF(MA50,3) AND Close>REF(MA50,1);

BK2= BK1==1 AND RAVI>=1 AND RAVI>REF(RAVI,1) AND REF(RAVI,1)>REF(RAVI,2) AND BKVOL==0;

If(BK2==1)

BK(X,New_Order);

SK1=Close<MA50 AND REF(Close,1)<REF(MA50,2) AND REF(Close,2)<REF(MA50,3) AND Close<REF(MA50,1);

SK2=SK1==1 AND RAVI>=1 AND RAVI>REF(RAVI,1) AND REF(RAVI,1)>REF(RAVI,2) AND SKVOL==0;

If(SK2==1)

SK(X,New_Order);

//以下为止盈

MONEY1=HIGH-VALUEWHEN(BK2==1,Close);

MONEY2=VALUEWHEN(SK2==1,Close)-Low;

MONEYB=Close-VALUEWHEN(BK2==1,Close);

PlotLine("MONEYB",MONEYB,White,Linethick2,2,0);

MONEYS=VALUEWHEN(SK2==1,Close)-Close;

ATRB=VALUEWHEN(BK2==1,ATR);

PlotLine("ATRB",ATRB,Blue,Linethick2,2,0);

ATRS=VALUEWHEN(SK2==1,ATR);

HVVB=HHV(MONEY1,BARSBK);

PlotLine("HVVB",HVVB,RED,Linethick2,2,0);

HVVS=HHV(MONEY2,BARSSK);

PlotLine("HVVS",HVVS,Magenta,Linethick2,2,0);

If(HVVB>=(W/10)*ATRB AND MONEYB<=HVVB/2 AND BKVOL>0)

SP(BKVOL,New_Order);//止盈平仓，卖平

If(HVVS>=(W/10)*ATRS AND MONEYS<=HVVS/2 AND SKVOL>0)

BP(SKVOL,New_Order);//止盈平仓，买平

//以下为止损

ZSBM=VALUEWHEN(BK2==1,Close)-ATRB*K/10;

ZSSM=VALUEWHEN(SK2==1,Close)+ATRS*K/10;

ZSB=Low<ZSBM AND BKVOL>0;//止损

ZSS=HIGH>ZSSM AND SKVOL>0;//止损

If(ZSB==1)

SP(BKVOL,New_Order);

If(ZSS==1)

BP(SKVOL,New_Order);

If(Close<MA50 AND BKVOL>0)

SP(BKVOL,New_Order);

If(Close>MA50 AND SKVOL>0)

BP(SKVOL,New_Order);

//用指数测试，交易主连合约，模型信号为次日的K线开盘价

End

投资者咨询：[求助]请老师帮忙转换为WH9的模型。 (文华财经wh9)

来源:文华财经日期:2019-11-2 16:15

以下是引用寻鹿在2019/11/2 18:13:00的发言：

工作日具体分析后为您回复

好的，谢谢您！

技术人员回复

日期:2019-11-4 16:37

参考3楼回复

投资者咨询：[求助]请老师帮忙转换为WH9的模型。 (文华财经wh9)

来源:文华财经日期:2019-11-2 16:15

以下是引用寻鹿在2019/11/4 16:37:00的发言：

参考3楼回复

请问一下，我用PTA指数所有历史数据测试，原来的WH8版本和您提供的WH9版本，对比测试报告发现信号个数都是223，但是前者交易143次，后者交易112次，是不是WH9少了的交易次数是不计算主连的移仓？

投资者咨询：[求助]请老师帮忙转换为WH9的模型。 (文华财经wh9)

来源:文华财经日期:2019-11-2 16:15

还有，我用棉花主连测试，发现对照原来的WH8版本和您提供的WH9版本的成交价格不同，WH8的符合次日开盘价，WH9的不是出信号的次日K线的开盘价，而是信号K线的当天收盘价而已

WH8的：

编号	时间	交易所	合约	信号	信号行	买卖	平开	价格
0	2004/6/4	郑州商品	CF411	SK	第12行	卖	开	13800
1	2004/7/12	郑州商品	CF411	BP	第32行	买	平	13375
2	2004/8/3	郑州商品	CF411	SK	第12行	卖	开	12920
3	2004/9/1	郑州商品	CF411	移仓		买	平	12580
4	2004/9/1	郑州商品	CF501	移仓		卖	开	12800

WH9的：

编号	时间	交易所	合约	信号	信号行	买卖	平开	价格	手数(平,开)	成交额	投保	平仓盈亏	可用资金	权益
0	2004/06/04	郑州商品	CF411	SK	第50行	卖	开	13765	0,1	68825	投机	---	94494	100000
1	2004/07/12	郑州商品	CF411	BP	第80行	买	平	13440	1,0	67200	投机	1625	101625	101625
2	2004/08/03	郑州商品	CF411	SK	第50行	卖	开	12845	0,2	128450	投机	---	91349	101625
3	2004/09/01	郑州商品	CF411	移仓		买	平	12580	2,0	125800	投机	2650	104275	104275
4	2004/09/01	郑州商品	CF501	移仓		卖	开	12800	0,2	128000	投机	---	94035	104275

技术人员回复

日期:2019-11-4 22:19

k线图右键补充历史数据，合约这里切换到主连合约，也补充全部数据看下

还有疑问，提供两个版本回测报告上半部分截图，我们分析下

投资者咨询：[求助]请老师帮忙转换为WH9的模型。 (文华财经wh9)

来源:文华财经日期:2019-11-2 16:15

以下是引用熙怡在2019/11/4 22:19:00的发言：

k线图右键补充历史数据，合约这里切换到主连合约，也补充全部数据看下

还有疑问，提供两个版本回测报告上半部分截图，我们分析下

都是补充到历史全部数据了，问题依旧~

截图如下：图一是WH8的，图二是WH9的

投资者咨询：[求助]请老师帮忙转换为WH9的模型。 (文华财经wh9)

来源:文华财经日期:2019-11-2 16:15

参数我修改了一下，变成20,15,80000,5,10，30

{{userData.name}}已认证

[求助]请老师帮忙转换为WH9的模型。 (文华财经wh9)

期货技术

高手榜

期货手续费

期权手续费

期货行情

期货全档行情