投资者咨询:【编写技巧】:经典指标汇总 (文华财经)
来源:文华财经 日期:2019-1-10 14:14
此贴总结了论坛上大家问的比较多的经典指标,包括:
E1:AC加速指标
E2:AO动量震荡指标
E3:AMV成本均价线
E4:捕捞季节指标
E5:缠论
E6:CYC成本指标
E7:地量群
E8:DKBY多空博弈指标
E9:鳄鱼线
E10:Force index强力指数指标
E11:顾比倒数
E12:顾比均线
E13:HPI 海利克精算指标
E14:HMA(Hull’s Moving Average)
E15:Heikiun Ashi 指标
E16:九转序列
E17:绝路航标
E18:KST万锭指标
E19:TRIX三重指数平滑移动平均指标
E20:UOS终极波动指标
E21:XLPL吸拉派落指标
E22:亚当理论的中心对称指标
E23:虚拟成交量
E25:TD序列:TD准备和TD倒数(德马克指标)
E26:镜像k线图(Y轴为对称轴)
――――――――――――――
PS:
1.指标仅作为思路拓展,但是不能直接实盘使用
大家可以根据这些指标进行改编,结合平时的交易经验,形成自己的交易方式
2. 指标均来自于论坛或者网络,是根据常见的方式改写的
技术人员回复
日期:2019-1-10 14:18
Y:=(HIGH+LOW)/2;
AO : =MA(Y ,5 )-MA(Y ,34 );
AC:=AO-MA( AO,5);
AC1:=REF(AC,1);
STICKLINE(AC>AC1,0,AC,COLORRED,0);
STICKLINE(AC<AC1,0,AC,COLORYELLOW,0);
BUY1:=REF(AC,3)<REF(AC1,3) AND REF(AC,2)<REF(AC1,2) AND REF(AC,2)<REF(AC,3) AND REF(AC,1)>REF(AC1,1) AND AC>AC1 AND COUNT(AC>0,4)=4;
DRAWTEXT(BUY1,AC, 'B'),COLORWHITE;
BUY2:=COUNT(AC<0,4)=4 AND REF(AC,3)<REF(AC1,3) AND COUNT(AC>AC1,3)=3;
DRAWTEXT(BUY2,AC, 'B'),COLORWHITE;
BUY3:=REF(AC,3)<REF(AC1,3) AND REF(AC,2)<REF(AC1,2) AND REF(AC,2)<REF(AC,3) AND COUNT(AC>AC1,2)=2 AND REF(AC,1)<0 AND AC>0;
DRAWTEXT(BUY3,AC, 'B'),COLORWHITE;
BUY4:=REF(AC,4)<REF(AC1,4) AND REF(AC,3)<REF(AC1,3) AND REF(AC,3)<REF(AC,4) AND COUNT(AC>AC1,3)=3 AND REF(AC,1)<0 AND AC>0;
DRAWTEXT(BUY4,AC, 'B'),COLORWHITE;
S1:=REF(AC,3)>REF(AC1,3) AND REF(AC,2)>REF(AC1,2) AND REF(AC,2)>REF(AC,3) AND REF(AC,1)<REF(AC1,1) AND AC<AC1 AND COUNT(AC<0,4)=4;
S2:=COUNT(AC>0,4)=4 AND REF(AC,3)>REF(AC1,3) AND COUNT(AC<AC1,3)=3;
DRAWTEXT(S2,AC, 'S'),COLORWHITE;
S3:=REF(AC,3)>REF(AC1,3) AND REF(AC,2)>REF(AC1,2) AND REF(AC,2)>REF(AC,3) AND COUNT(AC<AC1,2)=2 AND REF(AC,1)>0 AND AC<0;
S4:=REF(AC,4)>REF(AC1,4) AND REF(AC,3)>REF(AC1,3) AND REF(AC,3)>REF(AC,4) AND COUNT(AC<AC1,3)=3 AND REF(AC,1)>0 AND AC<0;
DRAWTEXT(S4,AC, 'S'),COLORWHITE;
PS:
1、属性为副图指标
2、指标适用软件:wh6,wh7,wh8
技术人员回复
日期:2019-1-10 14:20
E2:AO动量震荡指标
AO:=MA(Y,5)-MA(Y,34);
AO1:=REF(AO,1);
STICKLINE(AO>AO1,0,AO,COLORRED,0);
STICKLINE(AO<AO1,0,AO,COLORYELLOW,0);
S1:=CROSS(0,AO);
DRAWICON(S1,AO,5),ALIGN0;
DRAWTEXT(S1,AO,'S'),COLORWHITE;
S2:=AO<0 AND REF(AO,1)>REF(AO,2) AND AO<REF(AO,1);
DRAWTEXT(S2,AO,'S'),COLORWHITE;
SCOUNT:=BARSLAST(AO<0);//上一次AO>0后到现在的周期数;
SD:=HHV(AO,SCOUNT);//求上面周期的最大AO;
SCOUNTD:=HHVBARS(AO,SCOUNT);//求最大值到现在的周期数;
S3:=AO>0 AND REF(AO,1)>REF(AO,2) AND AO<REF(AO,1);//满足峰的条件;
S31:=COUNT(S3,SCOUNTD);//满足上面条件的次数;
DRAWTEXT(S31>=2 AND S3,AO,'S'),COLORWHITE;
B1:=CROSS(AO,0);
DRAWTEXT(B1,AO,'B'),COLORWHITE;
B2:=AO>0 AND REF(AO,1)<REF(AO,2) AND AO>REF(AO,1);
DRAWTEXT(B2,AO,'B'),COLORWHITE;
BCOUNT:=BARSLAST(AO>0);//上一次AO>0后到现在的周期数;
BD:=LLV(AO,BCOUNT);//求上面周期的最小AO;
BCOUNTD:=LLVBARS(AO,BCOUNT);//求最小值到现在的周期数;
B3:=AO<0 AND REF(AO,1)<REF(AO,2) AND AO>REF(AO,1);//满足峰的条件;
B31:=COUNT(B3,BCOUNTD);//满足上面条件的次数;
DRAWTEXT(B31>=2 AND B3,AO,'B'),COLORWHITE;
PS:
1、属性为副图指标
2、指标适用软件:wh6,wh7,wh8
技术人员回复
日期:2019-1-10 14:23
E3:AMV成本均价线
M1:=5;
M2:=13;
M3:=34;
M4:=250;
AMOV:=V*(O+C)/2;
AMV1:SUM(AMOV,M1)/SUM(V,M1);
AMV2:SUM(AMOV,M2)/SUM(V,M2);
AMV3:SUM(AMOV,M3)/SUM(V,M3);
AMV4:SUM(AMOV,M4)/SUM(V,M4);
PS:
1、属性为k线附属指标
2、指标适用软件:wh6,wh7,wh8
技术人员回复
日期:2019-1-10 14:27
E4:捕捞季节指标
WY1001:=(2*CLOSE+HIGH+LOW)/4;
WY1002:=EMA(WY1001,4);
WY1003:=EMA(WY1002,4);
WY1004:=EMA(WY1003,4);
XYS0:(WY1004-REF(WY1004,1))/REF(WY1004,1)*100;
STICKLINE1(XYS0>=0,XYS0,0,2,0),COLORRED;
STICKLINE1(XYS0<0,XYS0,0,2,0),COLORGREEN;
AMOUNT:=VOL*GETPRICE('AVPRICE');
PJGJ:=AMOUNT/VOL/100;
SSRYDJX:=MA(PJGJ,13);
SSRCJL:=EMA(VOL,13);
SSRCJE:=EMA(AMOUNT,13);
SSRCBJX:=(SSRCJE/SSRCJL/100)*100;
CYS13:=((CLOSE-SSRCBJX)/SSRCBJX)*100;
CAPITAL:=GETPRICE1('流通股本');
XYSHSL:=EMA(VOL/CAPITAL*100,13)/10000;
ZZX:0,COLORWHITE;
STICKLINE1(XYSHSL>6.1 AND CYS13>5,1,0,2,0),COLORGREEN;
STICKLINE1(XYSHSL>3.8 AND CYS13>5,0.75,0,2,0),COLORYELLOW;
STICKLINE1(XYSHSL>2.1 AND CYS13>5,0.5,0,2,0),COLORCYAN;
STICKLINE1(XYSHSL>1.8 AND CYS13>5,0.25,0,2,0),COLORBLUE;
XYS1:MA(XYS0,2),COLORYELLOW;
XYS2:MA(XYS0,1),COLORMAGENTA;
PS:
1、适用于股票
2、属性为副图指标
3、指标适用软件:wh6,wh7,wh8
技术人员回复
日期:2019-1-10 14:29
E5:缠论
之前的精华帖中,提供了相关源码
PS:
1、属性为k线附属指标
2、指标适用软件:wh6,wh7,wh8
技术人员回复
日期:2019-1-10 14:39
E6:CYC成本指标
P1:=5;
P2:=13;
P3:=34;
N:=BARSLAST(DATE<>REF(DATE,1))+1;
DYNAINFO8:=SUM(V,N);
DYNAINFO10:=OPI;
DYNAINFO3:=REF(C,N);
DYNAINFO5:=HHV(H,N);
DYNAINFO6:=LLV(L,N);
AMOUNT:=AVPRICE*V;
FINANCE7:=GETPRICE1('流通股本');
JJJ:=IF(DYNAINFO8>0.01,0.01*DYNAINFO10/DYNAINFO8,DYNAINFO3);
DDD:=(DYNAINFO5<0.01 || DYNAINFO6<0.01);
JJJT:=IF(DDD,1,(JJJ<(DYNAINFO5+0.01) && JJJ>(DYNAINFO6-0.01)));
CYC1:IF(JJJT,0.01*EMA(AMOUNT,P1)/EMA(VOL,P1),EMA((HIGH+LOW+CLOSE)/3,P1));
CYC2:IF(JJJT,0.01*EMA(AMOUNT,P2)/EMA(VOL,P2),EMA((HIGH+LOW+CLOSE)/3,P2));
CYC3:IF(JJJT,0.01*EMA(AMOUNT,P3)/EMA(VOL,P3),EMA((HIGH+LOW+CLOSE)/3,P3));
CYC∞:IF(JJJT,DMA(AMOUNT/(100*VOL),100*VOL/FINANCE7),EMA((HIGH+LOW+CLOSE)/3,120));
PS:
1、适用于股票
3、指标适用软件:wh6,wh7,wh8
技术人员回复
日期:2019-1-10 14:45
M1:=5;
M2:=35;
NN:=9;
VOLUME:=VOL,VOLSTICK;
MAVOL1:=MA(VOLUME,M1);
MAVOL2:=MA(VOLUME,M2);
绿低量:=13;
红低量:=55;
灰低量:=100;
N1:=21;
AMOUNT:=AVPRICE*V;
SAT:=(AMOUNT/C)/(HHV(AMOUNT,20)/HHV(C,20));
量能饱和:IF(SAT>1,1,SAT)*100,COLORRED,NODRAW;
中点:=REFX1(HHV(V,180)*0.5,10000);
CURRBARSCOUNT:=DATACOUNT-BARPOS+1;
STICKLINE(CURRBARSCOUNT=N1,中点*1.9,中点*1.52,COLOR00AAFF,1);
STICKLINE(CURRBARSCOUNT=N1,中点*1.88,中点*1.55,COLORRED,0);
DRAWTEXT(CURRBARSCOUNT=N1+3,中点*1.7,'饱和度'),COLORYELLOW;
H_L:=0.1*REFX1(HHV(VOL,240),10000);
MAV10:MA(V,10),COLORYELLOW;
启动5:=MA(V,5),COLORWHITE;
洗盘40:=MA(V,40),COLORBLUE;
异动135:=MA(V,135),COLORMAGENTA;
FROMOPEN:=IF(HOUR<12,60*(HOUR-9)-30+MINUTE,120+60*(HOUR-13)+MINUTE);
VVOL:=IF(CURRBARSCOUNT=1 AND PERIOD=5,VOL*240/FROMOPEN,NULL);
STICKLINE(CURRBARSCOUNT=1 AND PERIOD=5,VVOL,0,1,-1),COLOR00C0C0;
量:VOL,VOLSTICK;
FINANCE7:GETPRICE1('流通股本');
换手: VOL*10000/FINANCE7,NODRAW;
换10T:=SUM(换手,10),NODRAW;
倍数:=1.9;
倍量: VOL>=REF(V,1)*倍数 AND (IF(C<O,C>REF(C,1),1)),COLORYELLOW,NODRAW;
倍缩: REF(V,1)>=VOL*倍数,COLORMAGENTA,NODRAW;
平量: RANGE(V/REF(V,1),0.97,1.03) AND BARSCOUNT(V)>=2,COLORWHITE,NODRAW;
低量10: VOL=LLV(VOL,绿低量) AND BARSCOUNT(V)>=绿低量,COLORGREEN,NODRAW;
低量50: VOL=LLV(VOL,红低量) AND BARSCOUNT(V)>=红低量,COLORRED,NODRAW;
地量:VOL=LLV(VOL,灰低量) AND BARSCOUNT(V)>=灰低量,COLORGRAY,NODRAW;
V1:=VOL*0.9;
V2:=VOL*0.8;
STICKLINE(倍量, 0,V1,1,0),COLORYELLOW;
STICKLINE(平量,0,V1,1,0),COLORWHITE;
STICKLINE(低量10,0,V2,1,0),COLORGREEN;
STICKLINE(低量50,0,V2,1,0),COLORRED;
STICKLINE(地量,0,V2,1,0),COLORGRAY;
STICKLINE(倍缩,0,V*0.45,1,0),COLORMAGENTA;
STICKLINE(C<O AND C>REF(C,1),0,V,0,0),COLORRED;
真阳或假阴:=C>O OR C>REF(C,1);
收阳:= REF(真阳或假阴,3);
倍量1:=REF(倍量,3);
高量:=REF(V,3)>=HHV(V,7);
三日不破:= LLV(C,3)>=REF(L,3);
价升:=COUNT(C>=REF(C,1),3)=3;
量缩:=COUNT(V<=REF(V,1),3)=3;
连阳:= COUNT(真阳或假阴,3)=3;
倍量将军柱:= 倍量1 AND 三日不破 AND 收阳;
高量将军柱:= 高量 AND 三日不破 AND 收阳;
将军柱:= 倍量将军柱 OR 高量将军柱;
黄金柱:= 将军柱 AND 价升 AND 量缩 AND 连阳 ;
STICKLINE(黄金柱,0.3*V,0.7*V,1,0),COLORRED;
DRAWICON(黄金柱,V*1.5,3);
V100:= V<=LLV(V,100)*1.2 AND V>0 AND BARSCOUNT(V)>=100;
百日地量群:=COUNT(V100,5)>=3;
DRAWTEXT(FILTER(百日地量群,4),V+3*H_L,'地量群'),COLORWHITE;
长阴短柱:=C/REF(C,1)<=0.96 AND V<HHV(V,30)/1.9;
DRAWTEXT(长阴短柱 ,V+1.6*H_L,'卖'),COLORGREEN;
CV:=CLOSE;
BBIBOLL:=(MA(CV,3)+MA(CV,6)+MA(CV,12)+MA(CV,24))/4;
UPR:=BBIBOLL+6*STD(BBIBOLL,11);
DWN:=BBIBOLL-6*STD(BBIBOLL,11);
QJJ:=VOL/((HIGH-LOW)*2-ABS(CLOSE-OPEN));
XVL:=(IF(CLOSE>OPEN,QJJ*(HIGH-LOW),IF(CLOSE<OPEN,QJJ*(HIGH-OPEN+CLOSE-LOW),VOL/2))+IF(CLOSE>OPEN,0-QJJ*(HIGH-CLOSE+OPEN-LOW),IF(CLOSE<OPEN,0-QJJ*(HIGH-LOW),0-VOL/2)));
HSL:=(XVL/3)/1.15;
攻击:=((HSL*0.55+(REF(HSL,1)*0.33))+(REF(HSL,2)*0.22));
LLJX:=EMA(攻击,3);
B1:=IF(SUM(LLJX,1)>REF(MA(SUM(LLJX,1),1),1),SUM(LLJX,1),NULL);
B2:=IF(SUM(LLJX,2)>REF(MA(SUM(LLJX,2),1),1),SUM(LLJX,2),NULL);
B3:=IF(SUM(LLJX,3)>REF(MA(SUM(LLJX,3),1),1),SUM(LLJX,3),NULL);
B4:=IF(SUM(LLJX,4)>REF(MA(SUM(LLJX,4),1),1),SUM(LLJX,4),NULL);
B5:=IF(SUM(LLJX,5)>REF(MA(SUM(LLJX,5),1),1),SUM(LLJX,5),NULL);
B6:=IF(SUM(LLJX,6)>REF(MA(SUM(LLJX,6),1),1),SUM(LLJX,6),NULL);
B7:=IF(SUM(LLJX,7)>REF(MA(SUM(LLJX,7),1),1),SUM(LLJX,7),NULL);
B8:=IF(SUM(LLJX,8)>REF(MA(SUM(LLJX,8),1),1),SUM(LLJX,8),NULL);
B9:=IF(SUM(LLJX,9)>REF(MA(SUM(LLJX,9),1),1),SUM(LLJX,9),NULL);
B10:=IF(SUM(LLJX,10)>REF(MA(SUM(LLJX,10),1),1),SUM(LLJX,10),NULL);
XG:=B1 AND B2 AND B3 AND B4 AND B5 AND B6 AND B7 AND B8 AND B9 AND B10 AND (CLOSE-OPEN)>=(UPR-BBIBOLL) AND V/REF(V,1)>=1.9;
DRAWICON(XG,V*1.1,13);
PS:
1、适用于股票
2、属性为副图指标
3、指标适用软件:wh6,wh7
技术人员回复
日期:2019-1-10 14:48
E8:DKBY多空博弈指标
VAR1:=(HHV(HIGH,21)-C)/(HHV(HIGH,21)-LLV(LOW,21))*100-10;
VAR2:=(C-LLV(LOW,21))/(HHV(HIGH,21)-LLV(LOW,21))*100;
VAR3:=SMA(VAR2,13,8);
多方: SMA(VAR3,13,8),COLORRED,LINETHICK2;
空方: SMA(VAR1,21,8),COLORGREEN;
0;
45;
90;
A:=MA(-100*(HHV(HIGH,34)-CLOSE)/(HHV(HIGH,34)-LLV(LOW,34)),19);
长期线:A+100,COLORYELLOW,LINETHICK3;
PS:
1、属性为副图指标
2、指标适用软件:wh6,wh7,wh8
技术人员回复
日期:2019-1-10 14:51