文章
文章用户商铺文档快讯有问必答话题

K线标注编写 (文华财经WH6赢顺V6.7)

投资者咨询：K线标注编写 (文华财经WH6赢顺V6.7)
来源:文华财经  日期:2018-11-22 8:58
 请老师帮忙写下:
1/当今天K线收阴且今天高点高于等于昨天高点,低点高于昨天低点,且昨天K线高点高于前天高点,低点高于前天低点时,在此K线上方标注为.绿色AA
2/当今天K线收阴且今天高点高于等于昨天高点,但是低点低于昨天低点时,只要前天K高点高于大前天高点,低点高于大前天低点时,在此K线上方也标注为绿色AA.
3/当昨日是阴线今天是阳线时,在此K线下方标注为红BB
4/当今天的高低点包括影线都在昨日K线之内时(其实就是内包线),阳线在K线下方标注为红色CC,阴线在K线上方标注为绿色CC.

5/当今天K线收阳且今天低点低于等于昨天低点,高点低于昨天高点,且昨天K线低点低于前天低点,高点低于前天低点时,在此K线下方标注为红色AA
6/当今天K线收阳且今天低点低于等于昨天低点,但是高点高于昨天高点时,只要前天K线低点低于大前天K线低点,高点低于大前天K线高点时,也在此K线下方标注为红AA.
7/当昨日是阳线今天收阴线时,在此K线上方标注为绿BB


技术人员回复
日期:2018-11-22 9:16
参考：

TJ1:=ISDOWN&&H>=REF(H,1)&&L>REF(L,1)&&REF(H,1)>REF(H,2)&&REF(L,1)>REF(H,2);
TJ2:=ISDOWN&&H>=REF(H,1)&&L<REF(L,1)&&REF(H,2)>REF(H,3)&&REF(L,3)&&REF(L,2)>REF(L,3);
DRAWTEXT(TJ1||TJ2,H,'AA'),COLORGREEN;
TJ3:=ISUP&&REF(ISDOWN,1);
DRAWTEXT(TJ3,L,'BB'),COLORRED,VALIGN0;
TJ41:=ISUP&&H<REF(H,1)&&L>REF(L,1);
TJ42:=ISDOWN&&H<REF(H,1)&&L>REF(L,1);
DRAWTEXT(TJ41,L,'CC'),COLORRED,VALIGN0;
DRAWTEXT(TJ42,H,'CC'),COLORGREEN;
TJ5:=ISUP&&L<=REF(L,1)&&H<REF(H,1)&&REF(L,1)<REF(L,2)&&REF(H,1)>REF(L,1);
TJ6:=ISUP&&L<=REF(L,1)&&H>REF(H,1)&&REF(L,2)<REF(L,3)&&REF(H,2)>REF(H,3);
DRAWTEXT(TJ5||TJ6,L,'AA'),COLORRED,VALIGN0;
TJ7:ISDOWN&&REF(ISUP,1);
DRAWTEXT(TJ7,H,'BB'),COLORGREEN;
投资者咨询：K线标注编写 (文华财经WH6赢顺V6.7)
来源:文华财经  日期:2018-11-22 8:58
 会有一些重叠的现像,比如这个K同时满足AA/BB/CC,这个要怎么解决
技术人员回复
日期:2018-11-22 10:05
您可以定义一下，同时满足多个条件时，按照哪个条件进行标注

例如，当同时满足红AA和红BB时，标注成红色AA，参考：

DRAWTEXT((TJ5||TJ6)=0&&TJ3,L,'BB'),COLORRED,VALIGN0;
投资者咨询：K线标注编写 (文华财经WH6赢顺V6.7)
来源:文华财经  日期:2018-11-22 8:58
 我不想选择其中一个,我需要全部显示出来,比如说AA第一行,BB可不可以标注在AA下面第二行,如果CC也满足就标注在BB下面第三行呢?
技术人员回复
日期:2018-11-22 10:14
那您这样试一下：

TJ1:=ISDOWN&&H>=REF(H,1)&&L>REF(L,1)&&REF(H,1)>REF(H,2)&&REF(L,1)>REF(H,2);
TJ2:=ISDOWN&&H>=REF(H,1)&&L<REF(L,1)&&REF(H,2)>REF(H,3)&&REF(L,3)&&REF(L,2)>REF(L,3);
DRAWTEXT(TJ1||TJ2,H,'AA'),COLORGREEN;
TJ3:=ISUP&&REF(ISDOWN,1);
DRAWTEXT(TJ3,L*0.99,'BB'),COLORRED,VALIGN0;
TJ41:=ISUP&&H<REF(H,1)&&L>REF(L,1);
TJ42:=ISDOWN&&H<REF(H,1)&&L>REF(L,1);
DRAWTEXT(TJ41,L*0.98,'CC'),COLORRED,VALIGN0;
DRAWTEXT(TJ42,H*1.02,'CC'),COLORGREEN;
TJ5:=ISUP&&L<=REF(L,1)&&H<REF(H,1)&&REF(L,1)<REF(L,2)&&REF(H,1)>REF(L,1);
TJ6:=ISUP&&L<=REF(L,1)&&H>REF(H,1)&&REF(L,2)<REF(L,3)&&REF(H,2)>REF(H,3);
DRAWTEXT(TJ5||TJ6,L,'AA'),COLORRED,VALIGN0;
TJ7:ISDOWN&&REF(ISUP,1);
DRAWTEXT(TJ7,H*1.01,'BB'),COLORGREEN;
投资者咨询：K线标注编写 (文华财经WH6赢顺V6.7)
来源:文华财经  日期:2018-11-22 8:58
 能做成预警和选股公式吗,当同时满足二个或以上条件时预警,比如AABB 或AACC或BBCC或AABBCC
技术人员回复
日期:2018-11-22 10:37
wh6中可以实现声音提示，参考：

(TJ1||TJ2)&&TJ7,SOUND('A');//同时满足绿AA和绿BB时声音提示

----------

公式预警和公式选股需要在高端看盘软件wh7中实现

wh7是付费版本，官网下载：http://www.wenhua.com.cn/

公式预警和公式选股可以参考软件说明书：http://www.wenhua.com.cn/new_guide/Wh7/view3-2.html

以同时满足绿色AA和绿色BB为例

预警公式参考：

(TJ1||TJ2)&&TJ7,SPARK;

选股公式参考：

(TJ1||TJ2)&&TJ7,SELECT;

 
投资者咨询：K线标注编写 (文华财经WH6赢顺V6.7)
来源:文华财经  日期:2018-11-22 8:58
 我想更改下采纳老师建议,二楼的公式显示方式改为,当只有一个条件满足时,只标满足的那个标注,
当同时满足二个条件时AABB,标注显示为AB,
当同时满足二个条件时AACC,标注显示为AC
当同时满足二个条件时BBCC,标注显示为BC,
当同时满足二个条件时AABBCC,标注显示为ABC,
技术人员回复
日期:2018-11-22 13:09
参考：

TJ1:=ISDOWN&&H>=REF(H,1)&&L>REF(L,1)&&REF(H,1)>REF(H,2)&&REF(L,1)>REF(H,2);
TJ2:=ISDOWN&&H>=REF(H,1)&&L<REF(L,1)&&REF(H,2)>REF(H,3)&&REF(L,3)&&REF(L,2)>REF(L,3);
TJ3:=ISUP&&REF(ISDOWN,1);
TJ41:=ISUP&&H<REF(H,1)&&L>REF(L,1);
TJ42:=ISDOWN&&H<REF(H,1)&&L>REF(L,1);
TJ5:=ISUP&&L<=REF(L,1)&&H<REF(H,1)&&REF(L,1)<REF(L,2)&&REF(H,1)>REF(L,1);
TJ6:=ISUP&&L<=REF(L,1)&&H>REF(H,1)&&REF(L,2)<REF(L,3)&&REF(H,2)>REF(H,3);
TJ7:=ISDOWN&&REF(ISUP,1);
DRAWTEXT((TJ1||TJ2)&&NOT(TJ7||TJ42),H,'AA'),COLORGREEN;
DRAWTEXT(TJ7&&NOT(TJ1||TJ2||TJ42),H,'BB'),COLORGREEN;
DRAWTEXT(TJ42&&NOT(TJ1||TJ2||TJ7),H,'CC'),COLORGREEN;
DRAWTEXT((TJ1||TJ2)&&TJ7&&NOT(TJ42),H,'AB'),COLORGREEN;
DRAWTEXT((TJ1||TJ2)&&TJ42&&NOT(TJ7),H,'AC'),COLORGREEN;
DRAWTEXT(NOT(TJ1||TJ2)&&TJ7&&TJ42,H,'BC'),COLORGREEN;
DRAWTEXT((TJ1||TJ2)&&TJ7&&TJ42,H,'ABC'),COLORGREEN;
DRAWTEXT(TJ3&&NOT(TJ5||TJ6||TJ41),L,'BB'),COLORRED,VALIGN0;
DRAWTEXT(TJ41&&NOT(TJ5||TJ6||TJ3),L,'CC'),COLORRED,VALIGN0;
DRAWTEXT((TJ5||TJ6)&&NOT(TJ3||TJ41),L,'AA'),COLORRED,VALIGN0;
DRAWTEXT((TJ5||TJ6)&&TJ3&&NOT(TJ41),L,'AB'),COLORRED,VALIGN0;
DRAWTEXT((TJ5||TJ6)&&TJ41&&NOT(TJ3),L,'AC'),COLORRED,VALIGN0;
DRAWTEXT(NOT(TJ5||TJ6)&&TJ41&&TJ3,L,'BC'),COLORRED,VALIGN0;
DRAWTEXT((TJ5||TJ6)&&TJ41&&TJ3,L,'ABC'),COLORRED,VALIGN0;