文章
文章用户商铺文档快讯有问必答话题

说明以下K线变色原理 (文华财经WH6赢顺V6.7)

投资者咨询：说明以下K线变色原理 (文华财经WH6赢顺V6.7)
来源:文华财经  日期:2018-6-26 14:54
 老师，您好，烦请老师说明以下K线变色原理
KG1:=VOL>REF(HHV(VOL,4),1);
W2:=OPEN-CLOSE;
HH1:=IF(H<REF(H,2)&&REF(H,1)<REF(H,2),REF(H,2),0);
LL1:=IF(L>REF(L,2)&&REF(L,1)>REF(L,2),REF(L,2),0);
HH2:=VALUEWHEN(HH1>0,HH1);
LL2:=VALUEWHEN(LL1>0,LL1);
KA1:=IF(CLOSE>HH2,-3,IF(CLOSE<LL2,1,0));
KA2:=VALUEWHEN(KA1<>0,KA1);
GA:=IF(KA2=1,HH2,LL2);
GA1:=VALUEWHEN(ISLASTBAR,GA);
DRAWNUMBER(L>0,GA1,GA1,0,COLORCYAN);
W1:=KA2; 
U1:=(HIGH+LOW+CLOSE)/3;
HT:=IF(OPEN>CLOSE,OPEN,CLOSE);
LT:=IF(OPEN<CLOSE,OPEN,CLOSE);
DRAWLINE(W1=1,HIGH,W1=1,HT,COLORCYAN);
DRAWLINE(W1=1,LOW,W1=1,LT,COLORCYAN);
DRAWLINE(W1=-3,HIGH,W1=-3,HT,COLORRED);
DRAWLINE(W1=-3,LOW,W1=-3,LT,COLORRED);
STICKLINE(W1>0,OPEN,CLOSE,COLORCYAN,1);
STICKLINE(W1<=0,OPEN,CLOSE,COLORRED,1);
P1:=MA(U1,5)+(REF(MA(CLOSE,5),2)-REF(MA(CLOSE,5),4));
P:=(P1+MA(CLOSE,4))/2;
A1:=REF(HIGH,2)>REF(HIGH,1)||REF(LOW,2)>REF(LOW,1);
A3:=HIGH>REF(HIGH,1)|| HIGH>REF(HIGH,2)||(HIGH-LOW)*0.3+LOW>P;
A31:=CLOSE>P&&REF(LOW,1)<P&&CLOSE>REF((HIGH+LOW)/2,1);
A4:=REF(MA(CLOSE,5),2)>REF(MA(CLOSE,5),1);
A5:=VALUEWHEN(A1&&A3&&A4&&A31,REF((HIGH+LOW)/2 ,1));
DRAWSL(A1&&A3&&A4&&A31,A5,0,4,0,COLORRED);
RSV:=(CLOSE-LLV(LOW,12))/(HHV(HIGH,12)-LLV(LOW,12))*100;
M:=SMA(RSV,3,1);
A:=EMA(M,3);
B:=EMA(A,3);
A6:=REF(LOW,2)<REF(LOW,1)||REF(HIGH,2)<REF(HIGH,1);
A7:=LOW<REF(LOW,1)|| LOW<REF(LOW,2)||(HIGH-LOW)*0.7+LOW<P;
A71:=CLOSE<P&&REF(HIGH,1)>P&&CLOSE<REF((HIGH+LOW)/2,1);
A8:=REF(MA(CLOSE,5),2)<REF(MA(CLOSE,5),1);
A9:=VALUEWHEN(A6&&A7&&A8&&A71,REF((HIGH+LOW)/2 ,1));
DRAWSL(A6&&A7&&A8&&A71,A9,0,4,0,COLORGREEN);
D:= VALUEWHEN(KG1, (HIGH+LOW)/2);
STICKLINE(W2>0&&W1<=0,OPEN,CLOSE,COLORRED,0);
STICKLINE(W2>0&&W1>0,OPEN,CLOSE,COLORCYAN,0);
 
技术人员回复
日期:2018-6-26 15:05
分析后回复


投资者咨询：说明以下K线变色原理 (文华财经WH6赢顺V6.7)
来源:文华财经  日期:2018-6-26 14:54
 好的，谢谢老师
技术人员回复
日期:2018-6-26 15:39
hh1与hh2的定义是 描述了两种形态

HH1:=IF(H<REF(H,2)&&REF(H,1)<REF(H,2),REF(H,2),0);//三根k线h依次减小，取第一根的最高
LL1:=IF(L>REF(L,2)&&REF(L,1)>REF(L,2),REF(L,2),0);//三根k线l依次增大，取第一根的最低

当收盘价>之前一个形态最高时，为红色

收盘价<之前一个形态最低时，为青色


投资者咨询：说明以下K线变色原理 (文华财经WH6赢顺V6.7)
来源:文华财经  日期:2018-6-26 14:54
 谢谢老师，还有个问题烦请老师解答，红绿横线是什么意思
技术人员回复
日期:2018-6-27 10:35
 对应语句翻译如下,参考：

KG1:=VOL>REF(HHV(VOL,4),1);
W2:=OPEN-CLOSE;
HH1:=IF(H<REF(H,2)&&REF(H,1)<REF(H,2),REF(H,2),0);
LL1:=IF(L>REF(L,2)&&REF(L,1)>REF(L,2),REF(L,2),0);
HH2:=VALUEWHEN(HH1>0,HH1);
LL2:=VALUEWHEN(LL1>0,LL1);
KA1:=IF(CLOSE>HH2,-3,IF(CLOSE<LL2,1,0));
KA2:=VALUEWHEN(KA1<>0,KA1);
GA:=IF(KA2=1,HH2,LL2);
GA1:=VALUEWHEN(ISLASTBAR,GA);
DRAWNUMBER(L>0,GA1,GA1,0,COLORCYAN);
W1:=KA2; 
U1:=(HIGH+LOW+CLOSE)/3;//高低收的均值
HT:=IF(OPEN>CLOSE,OPEN,CLOSE);
LT:=IF(OPEN<CLOSE,OPEN,CLOSE);
DRAWLINE(W1=1,HIGH,W1=1,HT,COLORCYAN);
DRAWLINE(W1=1,LOW,W1=1,LT,COLORCYAN);
DRAWLINE(W1=-3,HIGH,W1=-3,HT,COLORRED);
DRAWLINE(W1=-3,LOW,W1=-3,LT,COLORRED);
STICKLINE(W1>0,OPEN,CLOSE,COLORCYAN,1);
STICKLINE(W1<=0,OPEN,CLOSE,COLORRED,1);
P1:=MA(U1,5)+(REF(MA(CLOSE,5),2)-REF(MA(CLOSE,5),4));//5周期高低收均值+两周期前5周期均线-4周期前五周期均线
P:=(P1+MA(CLOSE,4))/2;//（P1+4周期均线）的均值
A1:=REF(HIGH,2)>REF(HIGH,1)||REF(LOW,2)>REF(LOW,1);//两周期前高价高于一周期前高价 或者 两周期前低价高于一周期低价
A3:=HIGH>REF(HIGH,1)|| HIGH>REF(HIGH,2)||(HIGH-LOW)*0.3+LOW>P;//本周期高价大于前一周期高价 或者 本周期高价大于前二周期高价 或者（高价-低价）的30%+低价>P
A31:=CLOSE>P&&REF(LOW,1)<P&&CLOSE>REF((HIGH+LOW)/2,1);//收盘价>P 同时 前一周期低价<P 同时收盘价>前一周期的（高价+低价）的均值
A4:=REF(MA(CLOSE,5),2)>REF(MA(CLOSE,5),1);//前两周期的5周期均线大于前一周期的5周期均线
A5:=VALUEWHEN(A1&&A3&&A4&&A31,REF((HIGH+LOW)/2 ,1));
DRAWSL(A1&&A3&&A4&&A31,A5,0,4,0,COLORRED);// 满足A1 A3 A31 A4 以其前一个周期的（高+低）的均值 画线
RSV:=(CLOSE-LLV(LOW,12))/(HHV(HIGH,12)-LLV(LOW,12))*100;
M:=SMA(RSV,3,1);
A:=EMA(M,3);
B:=EMA(A,3);
A6:=REF(LOW,2)<REF(LOW,1)||REF(HIGH,2)<REF(HIGH,1);//两周期前高价低于一周期前高价 或者 两周期前低价低于一周期低价
A7:=LOW<REF(LOW,1)|| LOW<REF(LOW,2)||(HIGH-LOW)*0.7+LOW<P;//本周期低价小于前一周期低价 或者 本周期低价小于前二周期低价 或者（高价-低价）的70%+低价<P
A71:=CLOSE<P&&REF(HIGH,1)>P&&CLOSE<REF((HIGH+LOW)/2,1);//收盘价<P 同时 前一周期高价>P 同时收盘价<前一周期的（高价+低价）的均值
A8:=REF(MA(CLOSE,5),2)<REF(MA(CLOSE,5),1);//前两周期的5周期均线小于前一周期的5周期均线
A9:=VALUEWHEN(A6&&A7&&A8&&A71,REF((HIGH+LOW)/2 ,1));
DRAWSL(A6&&A7&&A8&&A71,A9,0,4,0,COLORGREEN);//满足A6 A7 A11 A8 以其前一个周期的（高+低）的均值 画线
D:= VALUEWHEN(KG1, (HIGH+LOW)/2);
STICKLINE(W2>0&&W1<=0,OPEN,CLOSE,COLORRED,0);
STICKLINE(W2>0&&W1>0,OPEN,CLOSE,COLORCYAN,0);