文章
文章用户商铺文档快讯有问必答话题

请帮助修改到赢顺公式 (文华财经WH6赢顺V6.7)

投资者咨询：请帮助修改到赢顺公式 (文华财经WH6赢顺V6.7)
来源:文华财经  日期:2018-7-8 9:13
 VAR1E:=FORCAST(IF(LOW=0,C,LOW),55);
VAR1F:=FORCAST(VAR1E,99);
VAR20:=LLV(CLOSE,70)*0.95;
VAR21:=HHV(CLOSE,70)*1.05;
操盘线:= IF(VAR1F>VAR21,VAR21,IF(VAR1F<VAR20,VAR20,VAR1F)), LINETHICK1,COLORCYAN;
DRAWGBK(c>操盘线,COLOR262644,COLOR424275,0); 
DRAWGBK(c<操盘线,COLOR345229,COLOR538341,0); 

DIF:100*(EMA(CLOSE,12)-EMA(CLOSE,26)),colorred;
DEA:EMA(DIF,9),colorgreen;
MACD:(DIF-DEA)*2,COLORSTICK，COLOR35F9F3;

死叉:=CROSS(DEA,DIF);
N1:=BARSLAST(死叉),NODRAW;{最近一次死叉的位置}
N2:=REF(BARSLAST(死叉),N1+1),NODRAW;{倒数第二次死叉与倒数第一次死叉的区间}
N3:=REF(BARSLAST(死叉),N2+N1+2),NODRAW;{倒数第三次死叉与倒数第二次死叉的区间}
CL1:=LLV(C,N1+1),NODRAW;{最近一次死叉后，最低收盘价}
DIFL1:=LLV(DIF,N1+1),NODRAW;

CL2:=REF(CL1,N1+1),NODRAW;{倒数第二次死叉与倒数第一次死叉之间的最低收盘价}
DIFL2:=REF(DIFL1,N1+1),NODRAW;
CL3:=REF(CL2,N1+1),NODRAW;{倒数第三次死叉与倒数第二次死叉之间的最低收盘价}


DIFL3:=REF(DIFL2,N1+1);
PDIFL2:=IF(DIFL2>0,INTPART(LOG(DIFL2))-1,INTPART(LOG(-DIFL2))-1);
MDIFL2:=INTPART(DIFL2/POW(10,PDIFL2));
PDIFL3:=IF(DIFL3>0,INTPART(LOG(DIFL3))-1,INTPART(LOG(-DIFL3))-1);
MDIFL3:=INTPART(DIFL3/POW(10,PDIFL3));
MDIFB2:=INTPART(DIF/POW(10,PDIFL2));
MDIFB3:=INTPART(DIF/POW(10,PDIFL3));
直接底背离:=(CL1<CL2 ) AND (MDIFB2>MDIFL2) AND (MACD<0 AND REF(MACD,1)<0) AND MDIFB2<=REF(MDIFB2,1);
隔峰底背离:=(CL1<CL3 AND CL3<CL2 ) AND (MDIFB3>MDIFL3) AND (MACD<0 AND REF(MACD,1)<0) AND MDIFB3<=REF(MDIFB3,1);
B:=(直接底背离 OR 隔峰底背离);
BG:=((MDIFB2>REF(MDIFB2,1))*REF(直接底背离,1)) OR ((MDIFB3>REF(MDIFB3,1))*REF(隔峰底背离,1));
底背离消失:=(REF(直接底背离,1) AND DIFL1<=DIFL2 ) OR (REF(隔峰底背离,1) AND DIFL1<=DIFL3);
STICKLINE(B OR BG,DIF,DEA,8,0),colorred;
DRAWTEXT((B AND COUNT(B,2)=1),(DIF*1.5),'钝化'),coloryellow;
DRAWTEXT(FILTER(BG,10),(DIF*1.5),'结构形成'),colormagenta;
DRAWTEXT(FILTER(底背离消失,10),(DIF+MACD),'消失'),colorgreen;
STICKLINE(BG,0,(DIF+DEA),5,0), colorred;

金叉:=CROSS(DIF,DEA);
M1:=BARSLAST(金叉),NODRAW;{最近一次金叉的位置}
M2:=REF(BARSLAST(金叉),M1+1),NODRAW;{倒数第二次金叉与倒数第一次金叉的区间}
M3:=REF(BARSLAST(金叉),M2+M1+2),NODRAW;{倒数第三次金叉与倒数第二次金叉的区间}
CH1:=HHV(C,M1+1),NODRAW;{最近一次金叉后，最高收盘价}
DIFH1:=HHV(DIF,M1+1),NODRAW;

CH2:=REF(CH1,M1+1),NODRAW;{倒数第二次金叉与倒数第一次金叉之间的最高收盘价}
DIFH2:=REF(DIFH1,M1+1),NODRAW;
CH3:=REF(CH2,M1+1),NODRAW;{倒数第三次金叉与倒数第二次金叉之间的最高收盘价}


DIFH3:=REF(DIFH2,M1+1);
PDIFH2:=IF(DIFH2>0,INTPART(LOG(DIFH2))-1,INTPART(LOG(-DIFH2))-1);
MDIFH2:=INTPART(DIFH2/POW(10,PDIFH2));
PDIFH3:=IF(DIFH3>0,INTPART(LOG(DIFH3))-1,INTPART(LOG(-DIFH3))-1);
MDIFH3:=INTPART(DIFH3/POW(10,PDIFH3));
MDIFT2:=INTPART(DIF/POW(10,PDIFH2));
MDIFT3:=INTPART(DIF/POW(10,PDIFH3));
直接顶背离:=(CH1>CH2 ) AND (MDIFT2<MDIFH2) AND (MACD>0 AND REF(MACD,1)>0) AND MDIFT2>=REF(MDIFT2,1);
隔峰顶背离:=(CH1>CH3 AND CH3>CH2 ) AND (MDIFT3<MDIFH3) AND (MACD>0 AND REF(MACD,1)>0) AND MDIFT3>=REF(MDIFT3,1);
T:=(直接顶背离 OR 隔峰顶背离);
TG:=((MDIFT2<REF(MDIFT2,1))*REF(直接顶背离,1)) OR ((MDIFT3<REF(MDIFT3,1))*REF(隔峰顶背离,1));
顶背离消失:=(REF(直接顶背离,1) AND DIFH1>=DIFH2 ) OR (REF(隔峰顶背离,1) AND DIFH1>=DIFH3);
STICKLINE(TG,0,(DIF+DEA),5,0), colorgreen;
STICKLINE(T OR TG,DIF,DEA,8,0),colorgreen;
DRAWTEXT(FILTER(TG,20),(DIF*1.4),'结构形成'),colormagenta;
DRAWTEXT(FILTER(顶背离消失,20),(DIF+MACD),'消失'),colorgreen;
DRAWICON(cross(dif,0),0,1) ;
DRAWICON(cross(0,dif),0,3) ;
DRAWICON(cross(dif,dea),dif,6) ;
DRAWICON(cross(dea,dif),dif,7) ;
DrawText(cross(dif,dea),dif,c),COLORF3EC58,linethick18;
DrawText(cross(dea,dif),dif,c),colorgreen,linethick18;

StickLine(cross(macd,0),0,macd,7,0),colorred;
StickLine(cross(0,macd),0,macd,7,0),colorgreen;

持续日期:=BARSLAST(cross(macd,0))+1;
信号结束:=BARSLAST(cross(0,macd))+1;
DRAWNUMBER(((macd>0) and ISLASTBAR),dif,if(持续日期>信号结束,0,持续日期),2),COLORD7AFDE,shift5;
DRAWNUMBER(((0>macd) and ISLASTBAR),dif,if(持续日期<信号结束,0,信号结束),2),colorgreen,shift5;
drawicon(macd>ref(macd,1) and ref(macd,1)<=ref(macd,2),macd,10);
drawicon(macd<ref(macd,1) and ref(macd,1)>=ref(macd,2),macd,11);



PDIFH2:=IF(DIFH2>0,INTPART(LOG(DIFH2))-1,INTPART(LOG(-DIFH2))-1);这里通不过，说后面不能跟-1
技术人员回复
日期:2018-7-8 10:30
  VAR1E:=FORCAST(IF(LOW=0,C,LOW),55);
VAR1F:=FORCAST(VAR1E,99);
VAR20:=LLV(CLOSE,70)*0.95;
VAR21:=HHV(CLOSE,70)*1.05;
操盘线:= IF(VAR1F>VAR21,VAR21,IF(VAR1F<VAR20,VAR20,VAR1F)), LINETHICK1,COLORCYAN;
DRAWGBK(C>操盘线,COLOR262644,COLOR424275,0); 
DRAWGBK(C<操盘线,COLOR345229,COLOR538341,0); 

DIF:100*(EMA(CLOSE,12)-EMA(CLOSE,26)),COLORRED;
DEA:EMA(DIF,9),COLORGREEN;
MACD:(DIF-DEA)*2,COLORSTICK,COLOR35F9F3;

死叉:=CROSS(DEA,DIF);
N1:=BARSLAST(死叉),NODRAW;
{最近一次死叉的位置}
N2:=REF(BARSLAST(死叉),N1+1),NODRAW;
{倒数第二次死叉与倒数第一次死叉的区间}
N3:=REF(BARSLAST(死叉),N2+N1+2),NODRAW;
{倒数第三次死叉与倒数第二次死叉的区间}
CL1:=LLV(C,N1+1),NODRAW;
{最近一次死叉后，最低收盘价}
DIFL1:=LLV(DIF,N1+1),NODRAW;
CL2:=REF(CL1,N1+1),NODRAW;

DIFL2:=REF(DIFL1,N1+1),NODRAW;
CL3:=REF(CL2,N1+1),NODRAW;
DIFL3:=REF(DIFL2,N1+1);
PDIFL2:=IF(DIFL2>0,INTPART(LOG(DIFL2))-1,INTPART(LOG(-1*DIFL2))-1);
MDIFL2:=INTPART(DIFL2/POW(10,PDIFL2));
PDIFL3:=IF(DIFL3>0,INTPART(LOG(DIFL3))-1,INTPART(LOG(-1*DIFL3))-1);
MDIFL3:=INTPART(DIFL3/POW(10,PDIFL3));
MDIFB2:=INTPART(DIF/POW(10,PDIFL2));
MDIFB3:=INTPART(DIF/POW(10,PDIFL3));
直接底背离:=(CL1<CL2 ) AND (MDIFB2>MDIFL2) AND (MACD<0 AND REF(MACD,1)<0) AND MDIFB2<=REF(MDIFB2,1);
隔峰底背离:=(CL1<CL3 AND CL3<CL2 ) AND (MDIFB3>MDIFL3) AND (MACD<0 AND REF(MACD,1)<0) AND MDIFB3<=REF(MDIFB3,1);
B:=(直接底背离 OR 隔峰底背离);
BG:=((MDIFB2>REF(MDIFB2,1))*REF(直接底背离,1)) OR ((MDIFB3>REF(MDIFB3,1))*REF(隔峰底背离,1));
底背离消失:=(REF(直接底背离,1) AND DIFL1<=DIFL2 ) OR (REF(隔峰底背离,1) AND DIFL1<=DIFL3);
STICKLINE1(B OR BG,DIF,DEA,8,0),COLORRED;
DRAWTEXT((B AND COUNT(B,2)=1),(DIF*1.5),'钝化'),COLORYELLOW;
DRAWTEXT(FILTER(BG,10),(DIF*1.5),'结构形成'),COLORMAGENTA;
DRAWTEXT(FILTER(底背离消失,10),(DIF+MACD),'消失'),COLORGREEN;
STICKLINE1(BG,0,(DIF+DEA),5,0), COLORRED;
金叉:=CROSS(DIF,DEA);
M1:=BARSLAST(金叉),NODRAW;
{最近一次金叉的位置}
M2:=REF(BARSLAST(金叉),M1+1),NODRAW;
{倒数第二次金叉与倒数第一次金叉的区间}
M3:=REF(BARSLAST(金叉),M2+M1+2),NODRAW;
{倒数第三次金叉与倒数第二次金叉的区间}
CH1:=HHV(C,M1+1),NODRAW;
DIFH1:=HHV(DIF,M1+1),NODRAW;
CH2:=REF(CH1,M1+1),NODRAW;
DIFH2:=REF(DIFH1,M1+1),NODRAW;
CH3:=REF(CH2,M1+1),NODRAW;
DIFH3:=REF(DIFH2,M1+1);
PDIFH2:=IF(DIFH2>0,INTPART(LOG(DIFH2))-1,INTPART(LOG(-1*DIFH2))-1);
MDIFH2:=INTPART(DIFH2/POW(10,PDIFH2));
PDIFH3:=IF(DIFH3>0,INTPART(LOG(DIFH3))-1,INTPART(LOG(-1*DIFH3))-1);
MDIFH3:=INTPART(DIFH3/POW(10,PDIFH3));
MDIFT2:=INTPART(DIF/POW(10,PDIFH2));
MDIFT3:=INTPART(DIF/POW(10,PDIFH3));
直接顶背离:=(CH1>CH2 ) AND (MDIFT2<MDIFH2) AND (MACD>0 AND REF(MACD,1)>0) AND MDIFT2>=REF(MDIFT2,1);
隔峰顶背离:=(CH1>CH3 AND CH3>CH2 ) AND (MDIFT3<MDIFH3) AND (MACD>0 AND REF(MACD,1)>0) AND MDIFT3>=REF(MDIFT3,1);
T:=(直接顶背离 OR 隔峰顶背离);
TG:=((MDIFT2<REF(MDIFT2,1))*REF(直接顶背离,1)) OR ((MDIFT3<REF(MDIFT3,1))*REF(隔峰顶背离,1));
顶背离消失:=(REF(直接顶背离,1) AND DIFH1>=DIFH2 ) OR (REF(隔峰顶背离,1) AND DIFH1>=DIFH3);
STICKLINE(TG,0,(DIF+DEA),5,0), COLORGREEN;
STICKLINE(T OR TG,DIF,DEA,8,0),COLORGREEN;
DRAWTEXT(FILTER(TG,20),(DIF*1.4),'结构形成'),COLORMAGENTA;
DRAWTEXT(FILTER(顶背离消失,20),(DIF+MACD),'消失'),COLORGREEN;
DRAWICON(CROSS(DIF,0),0,1) ;
DRAWICON(CROSS(0,DIF),0,3) ;
DRAWICON(CROSS(DIF,DEA),DIF,6) ;
DRAWICON(CROSS(DEA,DIF),DIF,7) ;
DRAWTEXT(CROSS(DIF,DEA),DIF,C),COLORF3EC58,LINETHICK7;
DRAWTEXT(CROSS(DEA,DIF),DIF,C),COLORGREEN,LINETHICK7;

STICKLINE1(CROSS(MACD,0),0,MACD,7,0),COLORRED;
STICKLINE1(CROSS(0,MACD),0,MACD,7,0),COLORGREEN;

持续日期:=BARSLAST(CROSS(MACD,0))+1;
信号结束:=BARSLAST(CROSS(0,MACD))+1;
DRAWNUMBER1(((MACD>0) AND ISLASTBAR),DIF,IF(持续日期>信号结束,0,持续日期),2),COLORD7AFDE,VALIGN2;
DRAWNUMBER1(((0>MACD) AND ISLASTBAR),DIF,IF(持续日期<信号结束,0,信号结束),2),COLORGREEN,VALIGN0;
DRAWICON(MACD>REF(MACD,1) AND REF(MACD,1)<=REF(MACD,2),MACD,10);
DRAWICON(MACD<REF(MACD,1) AND REF(MACD,1)>=REF(MACD,2),MACD,11);

投资者咨询：请帮助修改到赢顺公式 (文华财经WH6赢顺V6.7)
来源:文华财经  日期:2018-7-8 9:13
 加载以后提示第76行即DRAWTEXT(CROSS(DIF,DEA),DIF,C),COLORF3EC58,LINETHICK7;：试图从不是字符串的变量中提取字符串！
请老师解决。
技术人员回复
日期:2018-7-8 17:05
 如下修改这句：

DRAWTEXT(CROSS(DIF,DEA),DIF,'A'),COLORF3EC58,LINETHICK7;