投资者咨询：求翻译成文华 (文华财经WH8赢智V8.2)
来源:文华财经 日期:2018-7-12 17:05
Params
Numeric Count_Break(5); // 多头或空头计数器突破阈值
Numeric Xlength(20); // X周期高低点
Numeric ReBalanceCount(30); // 重平衡周期
Numeric lots(1);
Vars
NumericSeries HighLine(0);
NumericSeries LowLine(0);
NumericSeries high_count(0); // 强势多头趋势计数器
NumericSeries low_count(0); // 强势空头趋势计数器
NumericSeries i_count(0);
Begin
// 求出Xlength周期高低点
HighLine = Highest(High[1],Xlength);
LowLine = Lowest(Low[1],Xlength);
// K线图的第一个Bar时，low_count high_count i_count恢复0值
if(CurrentBar==0)
{
low_count=0;
high_count=0;
i_count=0;
}
// 每30个K线周期时，low_count high_count i_count恢复0值
if(i_count==ReBalanceCount)
{
low_count=0;
high_count=0;
i_count=0;
}
// 收盘价超越Xlength周期高点――强势多头趋势
// low_count计数器自减
// high_count计数器自增
if(close[1]>HighLine[1] )
{
high_count=high_count+1;
low_count=low_count-1;
}
// 收盘价低于Xlength周期低点――强势空头趋势
// low_count计数器自增
// high_count计数器自减
if(close[1]<LowLine[1])
{
high_count=high_count-1;
low_count=low_count+1;
}
// ========= 交易指令 =========
// 如果强势多头的累计数量，大于计数器阈值
if(high_count>Count_Break && MarketPosition<>1 )
{
buy(lots,open);
}
// 如果强势空头的累计数量，大于计数器阈值
if(low_count>Count_Break && MarketPosition<>-1)
{
sellshort(lots,open);
}
// 每根K线i_count自增
i_count=i_count+1;
Commentary("HighLine="+Text(HighLine));
Commentary("LowLine="+Text(LowLine));
Commentary("low_count="+Text(low_count));
Commentary("high_count="+Text(high_count));
Commentary("i_count="+Text(i_count));
End
技术人员回复
日期:2018-7-12 17:35
投资者咨询：求翻译成文华 (文华财经WH8赢智V8.2)
来源:文华财经 日期:2018-7-12 17:05
VARIABLE: LOW_COUNT:=0,HIGH_COUNT:=0,I_COUNT:=0;
FUND:=50000;
LOTS : =MAX(1,INTPART(FUND/(O*UNIT*0.1)));
HIGHLINE:=HHV(HIGH,20);
LOWLINE:=LLV(LOW,20);
IF BARPOS=0 THEN BEGIN
LOW_COUNT:=0;
HIGH_COUNT:=0;
I_COUNT:=0;
END
IF I_COUNT=30 THEN BEGIN
LOW_COUNT:=0;
HIGH_COUNT:=0;
I_COUNT:=0;
END
IF REF(CLOSE,1)>REF(HIGHLINE,1) THEN BEGIN
HIGH_COUNT:=HIGH_COUNT+1;
LOW_COUNT:=LOW_COUNT-1;
END
IF REF(CLOSE,1)<REF(LOWLINE,1) THEN BEGIN
HIGH_COUNT:=HIGH_COUNT-1;
LOW_COUNT:=LOW_COUNT+1;
END
IF (HIGH_COUNT>5 AND BKVOL=0) THEN BEGIN
BPK(LOTS);
END
IF (LOW_COUNT>5 AND SKVOL=0) THEN BEGIN
SPK(LOTS);
END
I_COUNT:=I_COUNT+1;
DRAWCOLORKLINE(BKVOL=0 AND SKVOL=0,COLORWHITE,0);
DRAWCOLORKLINE(SKVOL>0,COLORGREEN,0);
DRAWCOLORKLINE(BKVOL>0,COLORRED,0);
TRADE_OTHER('AUTO');
技术人员回复
日期:2018-7-12 18:15
